home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / gnu / emacs.lha / emacs-19.16 / lisp / files.el < prev    next >
Lisp/Scheme  |  1993-07-03  |  77KB  |  1,939 lines
  1. ;;; files.el --- file input and output commands for Emacs
  2.  
  3. ;; Copyright (C) 1985, 1986, 1987, 1992, 1993 Free Software Foundation, Inc.
  4.  
  5. ;; Maintainer: FSF
  6.  
  7. ;; This file is part of GNU Emacs.
  8.  
  9. ;; GNU Emacs is free software; you can redistribute it and/or modify
  10. ;; it under the terms of the GNU General Public License as published by
  11. ;; the Free Software Foundation; either version 2, or (at your option)
  12. ;; any later version.
  13.  
  14. ;; GNU Emacs is distributed in the hope that it will be useful,
  15. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. ;; GNU General Public License for more details.
  18.  
  19. ;; You should have received a copy of the GNU General Public License
  20. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22.  
  23. ;;; Commentary:
  24.  
  25. ;; Defines most of Emacs's file- and directory-handling functions,
  26. ;; including basic file visiting, backup generation, link handling,
  27. ;; ITS-id version control, load- and write-hook handling, and the like.
  28.  
  29. ;;; Code:
  30.  
  31. (defconst delete-auto-save-files t
  32.   "*Non-nil means delete a buffer's auto-save file when the buffer is saved.")
  33.  
  34. (defconst directory-abbrev-alist
  35.   nil
  36.   "*Alist of abbreviations for file directories.
  37. A list of elements of the form (FROM . TO), each meaning to replace
  38. FROM with TO when it appears in a directory name.  This replacement is
  39. done when setting up the default directory of a newly visited file.
  40. *Every* FROM string should start with `^'.
  41.  
  42. Use this feature when you have directories which you normally refer to
  43. via absolute symbolic links.  Make TO the name of the link, and FROM
  44. the name it is linked to.")
  45.  
  46. ;;; Turn off backup files on VMS since it has version numbers.
  47. (defconst make-backup-files (not (eq system-type 'vax-vms))
  48.   "*Non-nil means make a backup of a file the first time it is saved.
  49. This can be done by renaming the file or by copying.
  50.  
  51. Renaming means that Emacs renames the existing file so that it is a
  52. backup file, then writes the buffer into a new file.  Any other names
  53. that the old file had will now refer to the backup file.  The new file
  54. is owned by you and its group is defaulted.
  55.  
  56. Copying means that Emacs copies the existing file into the backup
  57. file, then writes the buffer on top of the existing file.  Any other
  58. names that the old file had will now refer to the new (edited) file.
  59. The file's owner and group are unchanged.
  60.  
  61. The choice of renaming or copying is controlled by the variables
  62. `backup-by-copying', `backup-by-copying-when-linked' and
  63. `backup-by-copying-when-mismatch'.")
  64.  
  65. ;; Do this so that local variables based on the file name
  66. ;; are not overridden by the major mode.
  67. (defvar backup-inhibited nil
  68.   "Non-nil means don't make a backup file for this buffer.")
  69. (put 'backup-inhibited 'permanent-local t)
  70.  
  71. (defconst backup-by-copying nil
  72.  "*Non-nil means always use copying to create backup files.
  73. See documentation of variable `make-backup-files'.")
  74.  
  75. (defconst backup-by-copying-when-linked nil
  76.  "*Non-nil means use copying to create backups for files with multiple names.
  77. This causes the alternate names to refer to the latest version as edited.
  78. This variable is relevant only if `backup-by-copying' is nil.")
  79.  
  80. (defconst backup-by-copying-when-mismatch nil
  81.   "*Non-nil means create backups by copying if this preserves owner or group.
  82. Renaming may still be used (subject to control of other variables)
  83. when it would not result in changing the owner or group of the file;
  84. that is, for files which are owned by you and whose group matches
  85. the default for a new file created there by you.
  86. This variable is relevant only if `backup-by-copying' is nil.")
  87.  
  88. (defvar backup-enable-predicate
  89.   '(lambda (name)
  90.      (or (< (length name) 5)
  91.      (not (string-equal "/tmp/" (substring name 0 5)))))
  92.   "Predicate that looks at a file name and decides whether to make backups.
  93. Called with an absolute file name as argument, it returns t to enable backup.")
  94.  
  95. (defconst buffer-offer-save nil
  96.   "*Non-nil in a buffer means offer to save the buffer on exit
  97. even if the buffer is not visiting a file.
  98. Automatically local in all buffers.")
  99. (make-variable-buffer-local 'buffer-offer-save)
  100.  
  101. (defconst find-file-existing-other-name nil
  102.   "*Non-nil means find a file under alternative names, in existing buffers.
  103. This means if any existing buffer is visiting the file you want
  104. under another name, you get the existing buffer instead of a new buffer.")
  105.  
  106. (defconst find-file-visit-truename nil
  107.   "*Non-nil means visit a file under its truename.
  108. The truename of a file is found by chasing all links
  109. both at the file level and at the levels of the containing directories.")
  110.  
  111. (defvar buffer-file-truename nil
  112.   "The truename of the file visited in the current buffer.
  113. This variable is automatically local in all buffers, when non-nil.")
  114. (make-variable-buffer-local 'buffer-file-truename)
  115. (put 'buffer-file-truename 'permanent-local t)
  116.  
  117. (defvar buffer-file-number nil
  118.   "The device number and file number of the file visited in the current buffer.
  119. The value is a list of the form (FILENUM DEVNUM).
  120. This pair of numbers uniquely identifies the file.
  121. If the buffer is visiting a new file, the value is nil.")
  122. (make-variable-buffer-local 'buffer-file-number)
  123. (put 'buffer-file-number 'permanent-local t)
  124.  
  125. (defconst file-precious-flag nil
  126.   "*Non-nil means protect against I/O errors while saving files.
  127. Some modes set this non-nil in particular buffers.")
  128.  
  129. (defvar version-control nil
  130.   "*Control use of version numbers for backup files.
  131. t means make numeric backup versions unconditionally.
  132. nil means make them for files that have some already.
  133. never means do not make them.")
  134.  
  135. (defvar dired-kept-versions 2
  136.   "*When cleaning directory, number of versions to keep.")
  137.  
  138. (defvar trim-versions-without-asking nil
  139.   "*If t, deletes excess backup versions silently.
  140. If nil, asks confirmation.  Any other value prevents any trimming.")
  141.  
  142. (defvar kept-old-versions 2
  143.   "*Number of oldest versions to keep when a new numbered backup is made.")
  144.  
  145. (defvar kept-new-versions 2
  146.   "*Number of newest versions to keep when a new numbered backup is made.
  147. Includes the new backup.  Must be > 0")
  148.  
  149. (defconst require-final-newline nil
  150.   "*Value of t says silently ensure a file ends in a newline when it is saved.
  151. Non-nil but not t says ask user whether to add a newline when there isn't one.
  152. nil means don't add newlines.")
  153.  
  154. (defconst auto-save-default t
  155.   "*Non-nil says by default do auto-saving of every file-visiting buffer.")
  156.  
  157. (defconst auto-save-visited-file-name nil
  158.   "*Non-nil says auto-save a buffer in the file it is visiting, when practical.
  159. Normally auto-save files are written under other names.")
  160.  
  161. (defconst save-abbrevs nil
  162.   "*Non-nil means save word abbrevs too when files are saved.
  163. Loading an abbrev file sets this to t.")
  164.  
  165. (defconst find-file-run-dired t
  166.   "*Non-nil says run dired if `find-file' is given the name of a directory.")
  167.  
  168. ;;;It is not useful to make this a local variable.
  169. ;;;(put 'find-file-not-found-hooks 'permanent-local t)
  170. (defvar find-file-not-found-hooks nil
  171.   "List of functions to be called for `find-file' on nonexistent file.
  172. These functions are called as soon as the error is detected.
  173. `buffer-file-name' is already set up.
  174. The functions are called in the order given until one of them returns non-nil.")
  175.  
  176. ;;;It is not useful to make this a local variable.
  177. ;;;(put 'find-file-hooks 'permanent-local t)
  178. (defvar find-file-hooks nil
  179.   "List of functions to be called after a buffer is loaded from a file.
  180. The buffer's local variables (if any) will have been processed before the
  181. functions are called.")
  182.  
  183. ;;; In case someone does make it local.
  184. (put 'write-file-hooks 'permanent-local t)
  185. (defvar write-file-hooks nil
  186.   "List of functions to be called before writing out a buffer to a file.
  187. If one of them returns non-nil, the file is considered already written
  188. and the rest are not called.
  189. These hooks are considered to pertain to the visited file.
  190. So this list is cleared if you change the visited file name.
  191. See also `write-contents-hooks'.
  192. Don't make this variable buffer-local; instead, use `local-write-file-hooks'.")
  193.  
  194. (put 'local-write-file-hooks 'permanent-local t)
  195. (defvar local-write-file-hooks nil
  196.   "Just like `write-file-hooks', except intended for per-buffer use.
  197. The functions in this list are called before the ones in
  198. `write-file-hooks'.")
  199.  
  200. (defvar write-contents-hooks nil
  201.   "List of functions to be called before writing out a buffer to a file.
  202. If one of them returns non-nil, the file is considered already written
  203. and the rest are not called.
  204. These hooks are considered to pertain to the buffer's contents,
  205. not to the particular visited file; thus, `set-visited-file-name' does
  206. not clear this variable, but changing the major mode does clear it.
  207. See also `write-file-hooks'.")
  208.  
  209. (defconst enable-local-variables t
  210.   "*Control use of local-variables lists in files you visit.
  211. The value can be t, nil or something else.
  212. A value of t means local-variables lists are obeyed;
  213. nil means they are ignored; anything else means query.
  214.  
  215. The command \\[normal-mode] always obeys local-variables lists
  216. and ignores this variable.")
  217.  
  218. (defconst enable-local-eval 'maybe
  219.   "*Control processing of the \"variable\" `eval' in a file's local variables.
  220. The value can be t, nil or something else.
  221. A value of t means obey `eval' variables;
  222. nil means ignore them; anything else means query.
  223.  
  224. The command \\[normal-mode] always obeys local-variables lists
  225. and ignores this variable.")
  226.  
  227. ;; Avoid losing in versions where CLASH_DETECTION is disabled.
  228. (or (fboundp 'lock-buffer)
  229.     (defalias 'lock-buffer 'ignore))
  230. (or (fboundp 'unlock-buffer)
  231.     (defalias 'unlock-buffer 'ignore))
  232.  
  233. (defun pwd ()
  234.   "Show the current default directory."
  235.   (interactive nil)
  236.   (message "Directory %s" default-directory))
  237.  
  238. (defvar cd-path nil
  239.   "Value of the CDPATH environment variable, as a list.
  240. Not actually set up until the first time you you use it.")
  241.  
  242. (defun parse-colon-path (cd-path)
  243.   "Explode a colon-separated list of paths into a string list."
  244.   (and cd-path
  245.        (let (cd-prefix cd-list (cd-start 0) cd-colon)
  246.      (setq cd-path (concat cd-path ":"))
  247.      (while (setq cd-colon (string-match ":" cd-path cd-start))
  248.        (setq cd-list
  249.          (nconc cd-list
  250.             (list (substitute-in-file-name
  251.                    (file-name-as-directory
  252.                 (substring cd-path cd-start cd-colon))))))
  253.        (setq cd-start (+ cd-colon 1)))
  254.      cd-list)))
  255.  
  256. (defun cd-absolute (dir)
  257.   "Change current directory to given absolute file name DIR."
  258.   (setq dir (expand-file-name dir))
  259.   (if (not (eq system-type 'vax-vms))
  260.       (setq dir (file-name-as-directory dir)))
  261.   (if (not (file-directory-p dir))
  262.       (error "%s is not a directory" dir)
  263.     (if (file-executable-p dir)
  264.     (setq default-directory dir)
  265.       (error "Cannot cd to %s:  Permission denied" dir))))
  266.  
  267. (defun cd (dir)
  268.   "Make DIR become the current buffer's default directory.
  269. If your environment includes a `CDPATH' variable, try each one of that
  270. colon-separated list of directories when resolving a relative directory name."
  271.   (interactive "FChange default directory: ")
  272.   (if (file-name-absolute-p dir)
  273.       (cd-absolute (expand-file-name dir))
  274.     (if (null cd-path)
  275.     (let ((trypath (parse-colon-path (getenv "CDPATH"))))
  276.       (setq cd-path (or trypath (list "./")))))
  277.     (if (not (catch 'found
  278.            (mapcar
  279.         (function (lambda (x)
  280.                 (let ((f (expand-file-name (concat x dir))))
  281.                   (if (file-directory-p f)
  282.                   (progn
  283.                     (cd-absolute f)
  284.                     (throw 'found t))))))
  285.         cd-path)
  286.            nil))
  287.     (error "No such directory found via CDPATH environment variable"))))
  288.  
  289. (defun load-file (file)
  290.   "Load the Lisp file named FILE."
  291.   (interactive "fLoad file: ")
  292.   (load (expand-file-name file) nil nil t))
  293.  
  294. (defun load-library (library)
  295.   "Load the library named LIBRARY.
  296. This is an interface to the function `load'."
  297.   (interactive "sLoad library: ")
  298.   (load library))
  299.  
  300. ;; OTHER is the other file to be compared.
  301. (defun file-local-copy (file)
  302.   "Copy the file FILE into a temporary file on this machine.
  303. Returns the name of the local copy, or nil, if FILE is directly
  304. accessible."
  305.   (let ((handler (find-file-name-handler file)))
  306.     (if handler
  307.     (funcall handler 'file-local-copy file)
  308.       nil)))
  309.  
  310. (defun file-truename (filename)
  311.   "Return the truename of FILENAME, which should be absolute.
  312. The truename of a file name is found by chasing symbolic links
  313. both at the level of the file and at the level of the directories
  314. containing it, until no links are left at any level."
  315.   (if (string= filename "~")
  316.       (progn
  317.     (setq filename (expand-file-name filename))
  318.     (if (string= filename "")
  319.         (setq filename "/"))))
  320.   (let ((handler (find-file-name-handler filename)))
  321.     ;; For file name that has a special handler, call handler.
  322.     ;; This is so that ange-ftp can save time by doing a no-op.
  323.     (if handler
  324.     (funcall handler 'file-truename filename)
  325.       (let ((dir (file-name-directory filename))
  326.         target dirfile)
  327.     ;; Get the truename of the directory.
  328.     (setq dirfile (directory-file-name dir))
  329.     ;; If these are equal, we have the (or a) root directory.
  330.     (or (string= dir dirfile)
  331.         (setq dir (file-name-as-directory (file-truename dirfile))))
  332.     (if (equal ".." (file-name-nondirectory filename))
  333.         (directory-file-name (file-name-directory (directory-file-name dir)))
  334.       (if (equal "." (file-name-nondirectory filename))
  335.           (directory-file-name dir)
  336.         ;; Put it back on the file name.
  337.         (setq filename (concat dir (file-name-nondirectory filename)))
  338.         ;; Is the file name the name of a link?
  339.         (setq target (file-symlink-p filename))
  340.         (if target
  341.         ;; Yes => chase that link, then start all over
  342.         ;; since the link may point to a directory name that uses links.
  343.         ;; We can't safely use expand-file-name here
  344.         ;; since target might look like foo/../bar where foo
  345.         ;; is itself a link.  Instead, we handle . and .. above.
  346.         (if (file-name-absolute-p target)
  347.             (file-truename target)
  348.           (file-truename (concat dir target)))
  349.           ;; No, we are done!
  350.           filename)))))))
  351.  
  352. (defun file-chase-links (filename)
  353.   "Chase links in FILENAME until a name that is not a link.
  354. Does not examine containing directories for links,
  355. unlike `file-truename'."
  356.   (let (tem (count 100) (newname filename))
  357.     (while (setq tem (file-symlink-p newname))
  358.       (if (= count 0)
  359.       (error "Apparent cycle of symbolic links for %s" filename))
  360.       ;; Handle `..' by hand, since it needs to work in the
  361.       ;; target of any directory symlink.
  362.       ;; This code is not quite complete; it does not handle
  363.       ;; embedded .. in some cases such as ./../foo and foo/bar/../../../lose.
  364.       (while (string-match "\\.\\./" tem)
  365.     (setq tem (substring tem 3))
  366.     (setq newname (file-name-as-directory
  367.                ;; Do the .. by hand.
  368.                (directory-file-name
  369.             (file-name-directory
  370.              ;; Chase links in the default dir of the symlink.
  371.              (file-chase-links
  372.               (directory-file-name
  373.                (file-name-directory newname))))))))
  374.       (setq newname (expand-file-name tem (file-name-directory newname)))
  375.       (setq count (1- count)))
  376.     newname))
  377.  
  378. (defun switch-to-buffer-other-window (buffer)
  379.   "Select buffer BUFFER in another window."
  380.   (interactive "BSwitch to buffer in other window: ")
  381.   (let ((pop-up-windows t))
  382.     (pop-to-buffer buffer t)))
  383.  
  384. (defun switch-to-buffer-other-frame (buffer)
  385.   "Switch to buffer BUFFER in another frame."
  386.   (interactive "BSwitch to buffer in other frame: ")
  387.   (let ((pop-up-frames t))
  388.     (pop-to-buffer buffer t)))
  389.  
  390. (defun find-file (filename)
  391.   "Edit file FILENAME.
  392. Switch to a buffer visiting file FILENAME,
  393. creating one if none already exists."
  394.   (interactive "FFind file: ")
  395.   (switch-to-buffer (find-file-noselect filename)))
  396.  
  397. (defun find-file-other-window (filename)
  398.   "Edit file FILENAME, in another window.
  399. May create a new window, or reuse an existing one.
  400. See the function `display-buffer'."
  401.   (interactive "FFind file in other window: ")
  402.   (switch-to-buffer-other-window (find-file-noselect filename)))
  403.  
  404. (defun find-file-other-frame (filename)
  405.   "Edit file FILENAME, in another frame.
  406. May create a new frame, or reuse an existing one.
  407. See the function `display-buffer'."
  408.   (interactive "FFind file in other frame: ")
  409.   (switch-to-buffer-other-frame (find-file-noselect filename)))
  410.  
  411. (defun find-file-read-only (filename)
  412.   "Edit file FILENAME but don't allow changes.
  413. Like \\[find-file] but marks buffer as read-only.
  414. Use \\[toggle-read-only] to permit editing."
  415.   (interactive "fFind file read-only: ")
  416.   (find-file filename)
  417.   (setq buffer-read-only t)
  418.   (current-buffer))
  419.  
  420. (defun find-file-read-only-other-window (filename)
  421.   "Edit file FILENAME in another window but don't allow changes.
  422. Like \\[find-file-other-window] but marks buffer as read-only.
  423. Use \\[toggle-read-only] to permit editing."
  424.   (interactive "fFind file read-only other window: ")
  425.   (find-file-other-window filename)
  426.   (setq buffer-read-only t)
  427.   (current-buffer))
  428.  
  429. (defun find-file-read-only-other-frame (filename)
  430.   "Edit file FILENAME in another frame but don't allow changes.
  431. Like \\[find-file-other-frame] but marks buffer as read-only.
  432. Use \\[toggle-read-only] to permit editing."
  433.   (interactive "fFind file read-only other frame: ")
  434.   (find-file-other-frame filename)
  435.   (setq buffer-read-only t)
  436.   (current-buffer))
  437.  
  438. (defun find-alternate-file (filename)
  439.   "Find file FILENAME, select its buffer, kill previous buffer.
  440. If the current buffer now contains an empty file that you just visited
  441. \(presumably by mistake), use this command to visit the file you really want."
  442.   (interactive
  443.    (let ((file buffer-file-name)
  444.      (file-name nil)
  445.      (file-dir nil))
  446.      (and file
  447.       (setq file-name (file-name-nondirectory file)
  448.         file-dir (file-name-directory file)))
  449.      (list (read-file-name
  450.         "Find alternate file: " file-dir nil nil file-name))))
  451.   (and (buffer-modified-p)
  452.        ;; (not buffer-read-only)
  453.        (not (yes-or-no-p (format "Buffer %s is modified; kill anyway? "
  454.                  (buffer-name))))
  455.        (error "Aborted"))
  456.   (let ((obuf (current-buffer))
  457.     (ofile buffer-file-name)
  458.     (onum buffer-file-number)
  459.     (otrue buffer-file-truename)
  460.     (oname (buffer-name)))
  461.     (rename-buffer " **lose**")
  462.     (setq buffer-file-name nil)
  463.     (setq buffer-file-number nil)
  464.     (setq buffer-file-truename nil)
  465.     (unwind-protect
  466.     (progn
  467.       (unlock-buffer)
  468.       (find-file filename))
  469.       (cond ((eq obuf (current-buffer))
  470.          (setq buffer-file-name ofile)
  471.          (setq buffer-file-number onum)
  472.          (setq buffer-file-truename otrue)
  473.          (lock-buffer)
  474.          (rename-buffer oname))))
  475.     (or (eq (current-buffer) obuf)
  476.     (kill-buffer obuf))))
  477.  
  478. (defun create-file-buffer (filename)
  479.   "Create a suitably named buffer for visiting FILENAME, and return it.
  480. FILENAME (sans directory) is used unchanged if that name is free;
  481. otherwise a string <2> or <3> or ... is appended to get an unused name."
  482.   (let ((lastname (file-name-nondirectory filename)))
  483.     (if (string= lastname "")
  484.     (setq lastname filename))
  485.     (generate-new-buffer lastname)))
  486.  
  487. (defun generate-new-buffer (name)
  488.   "Create and return a buffer with a name based on NAME.
  489. Choose the buffer's name using `generate-new-buffer-name'."
  490.   (get-buffer-create (generate-new-buffer-name name)))
  491.  
  492. (defconst automount-dir-prefix "^/tmp_mnt/"
  493.   "Regexp to match the automounter prefix in a directory name.")
  494.  
  495. (defvar abbreviated-home-dir nil
  496.   "The the user's homedir abbreviated according to `directory-abbrev-list'.")
  497.  
  498. (defun abbreviate-file-name (filename)
  499.   "Return a version of FILENAME shortened using `directory-abbrev-alist'.
  500. This also substitutes \"~\" for the user's home directory.
  501. Type \\[describe-variable] directory-abbrev-alist RET for more information."
  502.   ;; Get rid of the prefixes added by the automounter.
  503.   (if (and (string-match automount-dir-prefix filename)
  504.        (file-exists-p (file-name-directory
  505.                (substring filename (1- (match-end 0))))))
  506.       (setq filename (substring filename (1- (match-end 0)))))
  507.   (let ((tail directory-abbrev-alist))
  508.     ;; If any elt of directory-abbrev-alist matches this name,
  509.     ;; abbreviate accordingly.
  510.     (while tail
  511.       (if (string-match (car (car tail)) filename)
  512.       (setq filename
  513.         (concat (cdr (car tail)) (substring filename (match-end 0)))))
  514.       (setq tail (cdr tail)))
  515.     ;; Compute and save the abbreviated homedir name.
  516.     ;; We defer computing this until the first time it's needed, to
  517.     ;; give time for directory-abbrev-alist to be set properly.
  518.     ;; We include a slash at the end, to avoid spurious matches
  519.     ;; such as `/usr/foobar' when the home dir is `/usr/foo'.
  520.     (or abbreviated-home-dir
  521.     (setq abbreviated-home-dir
  522.           (let ((abbreviated-home-dir "$foo"))
  523.         (concat "^" (abbreviate-file-name (expand-file-name "~"))
  524.             "\\(/\\|$\\)"))))
  525.                           
  526.     ;; If FILENAME starts with the abbreviated homedir,
  527.     ;; make it start with `~' instead.
  528.     (if (string-match abbreviated-home-dir filename)
  529.     (setq filename
  530.           (concat "~"
  531.               ;; If abbreviated-home-dir ends with a slash,
  532.               ;; don't remove the corresponding slash from
  533.               ;; filename.  On MS-DOS and OS/2, you can have
  534.               ;; home directories like "g:/", in which it is
  535.               ;; important not to remove the slash.  And what
  536.               ;; about poor root on Unix systems?
  537.               (if (eq ?/ (aref abbreviated-home-dir
  538.                        (1- (length abbreviated-home-dir))))
  539.               "/"
  540.             "")
  541.               (substring filename (match-beginning 1) (match-end 1))
  542.               (substring filename (match-end 0)))))
  543.     filename))
  544.  
  545. (defvar find-file-not-true-dirname-list nil
  546.   "*List of logical names for which visiting shouldn't save the true dirname.
  547. On VMS, when you visit a file using a logical name that searches a path,
  548. you may or may not want the visited file name to record the specific
  549. directory where the file was found.  If you *do not* want that, add the logical
  550. name to this list as a string.")
  551.  
  552. (defun find-file-noselect (filename &optional nowarn)
  553.   "Read file FILENAME into a buffer and return the buffer.
  554. If a buffer exists visiting FILENAME, return that one, but
  555. verify that the file has not changed since visited or saved.
  556. The buffer is not selected, just returned to the caller."
  557.   (setq filename
  558.     (abbreviate-file-name
  559.      (expand-file-name filename)))
  560.   (if (file-directory-p filename)
  561.       (if find-file-run-dired
  562.       (dired-noselect filename)
  563.     (error "%s is a directory." filename))
  564.     (let* ((buf (get-file-buffer filename))
  565.        (truename (abbreviate-file-name (file-truename filename)))
  566.        (number (nthcdr 10 (file-attributes truename)))
  567.        ;; Find any buffer for a file which has same truename.
  568.        (same-truename
  569.         (or buf ; Shortcut
  570.         (let (found
  571.               (list (buffer-list)))
  572.           (while (and (not found) list)
  573.             (save-excursion
  574.               (set-buffer (car list))
  575.               (if (and buffer-file-name
  576.                    (string= buffer-file-truename truename))
  577.             (setq found (car list))))
  578.             (setq list (cdr list)))
  579.           found)))
  580.        (same-number
  581.         (or buf ; Shortcut
  582.         (and number
  583.              (let (found
  584.                (list (buffer-list)))
  585.                (while (and (not found) list)
  586.              (save-excursion
  587.                (set-buffer (car list))
  588.                (if (and (equal buffer-file-number number)
  589.                     ;; Verify this buffer's file number
  590.                     ;; still belongs to its file.
  591.                     (file-exists-p buffer-file-name)
  592.                     (equal (nthcdr 10 (file-attributes buffer-file-name)) number))
  593.                  (setq found (car list))))
  594.              (setq list (cdr list)))
  595.                found))))
  596.        error)
  597.       ;; Let user know if there is a buffer with the same truename.
  598.       (if (and (not buf) same-truename (not nowarn))
  599.       (message "%s and %s are the same file (%s)"
  600.            filename (buffer-file-name same-truename)
  601.            truename)
  602.     (if (and (not buf) same-number (not nowarn))
  603.       (message "%s and %s are the same file"
  604.            filename (buffer-file-name same-number))))
  605.  
  606.       ;; Optionally also find that buffer.
  607.       (if (or find-file-existing-other-name find-file-visit-truename)
  608.       (setq buf (or same-truename same-number)))
  609.       (if buf
  610.       (or nowarn
  611.           (verify-visited-file-modtime buf)
  612.           (cond ((not (file-exists-p filename))
  613.              (error "File %s no longer exists!" filename))
  614.             ((yes-or-no-p
  615.               (format
  616.                (if (buffer-modified-p buf)
  617.     "File %s changed on disk.  Discard your edits? "
  618.     "File %s changed on disk.  Read the new version? ")
  619.                (file-name-nondirectory filename)))
  620.              (save-excursion
  621.                (set-buffer buf)
  622.                (revert-buffer t t)))))
  623.     (save-excursion
  624. ;;; The truename stuff makes this obsolete.
  625. ;;;      (let* ((link-name (car (file-attributes filename)))
  626. ;;;         (linked-buf (and (stringp link-name)
  627. ;;;                  (get-file-buffer link-name))))
  628. ;;;        (if (bufferp linked-buf)
  629. ;;;        (message "Symbolic link to file in buffer %s"
  630. ;;;             (buffer-name linked-buf))))
  631.       (setq buf (create-file-buffer filename))
  632.       (set-buffer buf)
  633.       (erase-buffer)
  634.       (condition-case ()
  635.           (insert-file-contents filename t)
  636.         (file-error
  637.          (setq error t)
  638.          ;; Run find-file-not-found-hooks until one returns non-nil.
  639.          (let ((hooks find-file-not-found-hooks))
  640.            (while (and hooks
  641.                (not (funcall (car hooks))))
  642.          (setq hooks (cdr hooks))))))
  643.       ;; Find the file's truename, and maybe use that as visited name.
  644.       (setq buffer-file-truename (abbreviate-file-name truename))
  645.       (setq buffer-file-number number)
  646.       ;; On VMS, we may want to remember which directory in a search list
  647.       ;; the file was found in.
  648.       (and (eq system-type 'vax-vms)
  649.            (let (logical)
  650.          (if (string-match ":" (file-name-directory filename))
  651.              (setq logical (substring (file-name-directory filename)
  652.                           0 (match-beginning 0))))
  653.          (not (member logical find-file-not-true-dirname-list)))
  654.            (setq buffer-file-name buffer-file-truename))
  655.       (if find-file-visit-truename
  656.           (setq buffer-file-name
  657.             (setq filename
  658.               (expand-file-name buffer-file-truename))))
  659.       ;; Set buffer's default directory to that of the file.
  660.       (setq default-directory (file-name-directory filename))
  661.       ;; Turn off backup files for certain file names.  Since
  662.       ;; this is a permanent local, the major mode won't eliminate it.
  663.       (and (not (funcall backup-enable-predicate buffer-file-name))
  664.            (progn
  665.          (make-local-variable 'backup-inhibited)
  666.          (setq backup-inhibited t)))
  667.       (after-find-file error (not nowarn))))
  668.       buf)))
  669.  
  670. (defun after-find-file (&optional error warn noauto)
  671.   "Called after finding a file and by the default revert function.
  672. Sets buffer mode, parses local variables.
  673. Optional args ERROR, WARN, and NOAUTO: ERROR non-nil means there was an
  674. error in reading the file.  WARN non-nil means warn if there
  675. exists an auto-save file more recent than the visited file.
  676. NOAUTO means don't mess with auto-save mode.
  677. Finishes by calling the functions in `find-file-hooks'."
  678.   (setq buffer-read-only (not (file-writable-p buffer-file-name)))
  679.   (if noninteractive
  680.       nil
  681.     (let* (not-serious
  682.        (msg
  683.         (cond ((and error (file-attributes buffer-file-name))
  684.            (setq buffer-read-only t)
  685.            "File exists, but is read-protected.")
  686.           ((not buffer-read-only)
  687.            (if (and warn
  688.                 (file-newer-than-file-p (make-auto-save-file-name)
  689.                             buffer-file-name))
  690.                "Auto save file is newer; consider M-x recover-file"
  691.              (setq not-serious t)
  692.              (if error "(New file)" nil)))
  693.           ((not error)
  694.            (setq not-serious t)
  695.            "Note: file is write protected")
  696.           ((file-attributes (directory-file-name default-directory))
  697.            "File not found and directory write-protected")
  698.           ((file-exists-p (file-name-directory buffer-file-name))
  699.            (setq buffer-read-only nil))
  700.           (t
  701.            (setq buffer-read-only nil)
  702.            (if (file-exists-p (file-name-directory (directory-file-name (file-name-directory buffer-file-name))))
  703.                "Use M-x make-dir RET RET to create the directory"
  704.              "Use C-u M-x make-dir RET RET to create directory and its parents")))))
  705.       (if msg
  706.       (progn
  707.         (message msg)
  708.         (or not-serious (sit-for 1 nil t)))))
  709.     (if (and auto-save-default (not noauto))
  710.     (auto-save-mode t)))
  711.   (normal-mode t)
  712.   (mapcar 'funcall find-file-hooks))
  713.  
  714. (defun normal-mode (&optional find-file)
  715.   "Choose the major mode for this buffer automatically.
  716. Also sets up any specified local variables of the file.
  717. Uses the visited file name, the -*- line, and the local variables spec.
  718.  
  719. This function is called automatically from `find-file'.  In that case,
  720. we may set up specified local variables depending on the value of
  721. `enable-local-variables': if it is t, we do; if it is nil, we don't;
  722. otherwise, we query.  `enable-local-variables' is ignored if you
  723. run `normal-mode' explicitly."
  724.   (interactive)
  725.   (or find-file (funcall (or default-major-mode 'fundamental-mode)))
  726.   (condition-case err
  727.       (set-auto-mode)
  728.     (error (message "File mode specification error: %s"
  729.             (prin1-to-string err))))
  730.   (condition-case err
  731.       (let ((enable-local-variables (or (not find-file)
  732.                     enable-local-variables)))
  733.     (hack-local-variables))
  734.     (error (message "File local-variables error: %s"
  735.             (prin1-to-string err)))))
  736.  
  737. (defvar auto-mode-alist (mapcar 'purecopy
  738.                 '(("\\.text\\'" . text-mode)
  739.                   ("\\.c\\'" . c-mode)
  740.                   ("\\.h\\'" . c-mode)
  741.                   ("\\.tex\\'" . TeX-mode)
  742.                   ("\\.ltx\\'" . LaTeX-mode)
  743.                   ("\\.el\\'" . emacs-lisp-mode)
  744.                   ("\\.mm\\'" . nroff-mode)
  745.                   ("\\.me\\'" . nroff-mode)
  746.                   ("\\.ms\\'" . nroff-mode)
  747.                   ("\\.man\\'" . nroff-mode)
  748.                   ("\\.scm\\'" . scheme-mode)
  749.                   ("\\.l\\'" . lisp-mode)
  750.                   ("\\.lisp\\'" . lisp-mode)
  751.                   ("\\.f\\'" . fortran-mode)
  752.                   ("\\.for\\'" . fortran-mode)
  753.                   ("\\.mss\\'" . scribe-mode)
  754.                   ("\\.pl\\'" . prolog-mode)
  755.                   ("\\.cc\\'" . c++-mode)
  756.                   ("\\.hh\\'" . c++-mode)
  757.                   ("\\.C\\'" . c++-mode)
  758.                   ("\\.H\\'" . c++-mode)
  759. ;;;                  ("\\.mk\\'" . makefile-mode)
  760. ;;;                  ("[Mm]akefile" . makefile-mode)
  761. ;;; Less common extensions come here
  762. ;;; so more common ones above are found faster.
  763.                   ("\\.s\\'" . asm-mode)
  764.                   ("ChangeLog\\'" . change-log-mode)
  765.                   ("ChangeLog.[0-9]+\\'" . change-log-mode)
  766.                   ("\\$CHANGE_LOG\\$\\.TXT" . change-log-mode)
  767. ;; The following should come after the ChangeLog pattern
  768. ;; for the sake of ChangeLog.1, etc.
  769.                   ("\\.[12345678]\\'" . nroff-mode)
  770.                   ("\\.TeX\\'" . TeX-mode)
  771.                   ("\\.sty\\'" . LaTeX-mode)
  772.                   ("\\.bbl\\'" . LaTeX-mode)
  773.                   ("\\.bib\\'" . bibtex-mode)
  774.                   ("\\.article\\'" . text-mode)
  775.                   ("\\.letter\\'" . text-mode)
  776.                   ("\\.texinfo\\'" . texinfo-mode)
  777.                   ("\\.texi\\'" . texinfo-mode)
  778.                   ("\\.lsp\\'" . lisp-mode)
  779.                   ("\\.awk\\'" . awk-mode)
  780.                   ("\\.prolog\\'" . prolog-mode)
  781.                   ("\\.tar\\'" . tar-mode)
  782.                   ;; Mailer puts message to be edited in
  783.                   ;; /tmp/Re.... or Message
  784.                   ("^/tmp/Re" . text-mode)
  785.                   ("/Message[0-9]*\\'" . text-mode)
  786.                   ;; some news reader is reported to use this
  787.                   ("^/tmp/fol/" . text-mode)
  788.                   ("\\.y\\'" . c-mode)
  789.                   ("\\.lex\\'" . c-mode)
  790.                   ("\\.oak\\'" . scheme-mode)
  791.                   ("\\.scm.[0-9]*\\'" . scheme-mode)
  792.                   ("\\.sgm\\'" . sgml-mode)
  793.                   ("\\.sgml\\'" . sgml-mode)
  794.                   ("\\.dtd\\'" . sgml-mode)
  795.                   ;; .emacs following a directory delimiter
  796.                   ;; in either Unix or VMS syntax.
  797.                   ("[]>:/]\\..*emacs\\'" . emacs-lisp-mode)
  798.                   ("\\.ml\\'" . lisp-mode)))
  799.   "\
  800. Alist of filename patterns vs corresponding major mode functions.
  801. Each element looks like (REGEXP . FUNCTION).
  802. Visiting a file whose name matches REGEXP causes FUNCTION to be called.")
  803.  
  804. (defconst inhibit-local-variables-regexps '("\\.tar$")
  805.   "List of regexps; if one matches a file name, don't look for local vars.")
  806.  
  807. (defun set-auto-mode ()
  808.   "Select major mode appropriate for current buffer.
  809. This checks for a -*- mode tag in the buffer's text, or
  810. compares the filename against the entries in auto-mode-alist.  It does
  811. not check for the \"mode:\" local variable in the Local Variables
  812. section of the file; for that, use `hack-local-variables'.
  813.  
  814. If `enable-local-variables' is nil, this function does not check for a
  815. -*- mode tag."
  816.   ;; Look for -*-MODENAME-*- or -*- ... mode: MODENAME; ... -*-
  817.   (let (beg end mode)
  818.     (save-excursion
  819.       (goto-char (point-min))
  820.       (skip-chars-forward " \t\n")
  821.       (if (and enable-local-variables
  822.            ;; Don't look for -*- if this file name matches any
  823.            ;; of the regexps in inhibit-local-variables-regexps.
  824.            (not (let ((temp inhibit-local-variables-regexps))
  825.               (while (and temp
  826.                   (not (string-match (car temp)
  827.                              buffer-file-name)))
  828.             (setq temp (cdr temp)))
  829.               (not temp)))
  830.            (search-forward "-*-" (save-excursion
  831.                        ;; If the file begins with "#!"
  832.                        ;; (exec interpreter magic), look
  833.                        ;; for mode frobs in the first two
  834.                        ;; lines.  You cannot necessarily
  835.                        ;; put them in the first line of
  836.                        ;; such a file without screwing up
  837.                        ;; the interpreter invocation.
  838.                        (end-of-line (and (looking-at "^#!") 2))
  839.                        (point)) t)
  840.            (progn
  841.          (skip-chars-forward " \t")
  842.          (setq beg (point))
  843.          (search-forward "-*-"
  844.                  (save-excursion (end-of-line) (point))
  845.                  t))
  846.            (progn
  847.          (forward-char -3)
  848.          (skip-chars-backward " \t")
  849.          (setq end (point))
  850.          (goto-char beg)
  851.          (if (search-forward ":" end t)
  852.              (progn
  853.                (goto-char beg)
  854.                (if (let ((case-fold-search t))
  855.                  (search-forward "mode:" end t))
  856.                (progn
  857.                  (skip-chars-forward " \t")
  858.                  (setq beg (point))
  859.                  (if (search-forward ";" end t)
  860.                  (forward-char -1)
  861.                    (goto-char end))
  862.                  (skip-chars-backward " \t")
  863.                  (setq mode (buffer-substring beg (point))))))
  864.            (setq mode (buffer-substring beg end)))))
  865.       (setq mode (intern (concat (downcase mode) "-mode")))
  866.     (if buffer-file-name
  867.         (let ((alist auto-mode-alist)
  868.           (name buffer-file-name))
  869.           (let ((case-fold-search (eq system-type 'vax-vms)))
  870.         ;; Remove backup-suffixes from file name.
  871.         (setq name (file-name-sans-versions name))
  872.         ;; Find first matching alist entry.
  873.         (while (and (not mode) alist)
  874.           (if (string-match (car (car alist)) name)
  875.               (setq mode (cdr (car alist))))
  876.           (setq alist (cdr alist))))))))
  877.     (if mode (funcall mode))))
  878.  
  879. (defun hack-local-variables-prop-line ()
  880.   ;; Set local variables specified in the -*- line.
  881.   ;; Returns t if mode was set.
  882.   (save-excursion
  883.     (goto-char (point-min))
  884.     (skip-chars-forward " \t\n\r")
  885.     (let ((result '())
  886.       (end (save-excursion (end-of-line) (point)))
  887.       mode-p)
  888.       ;; Parse the -*- line into the `result' alist.
  889.       (cond ((not (search-forward "-*-" end t))
  890.          ;; doesn't have one.
  891.          nil)
  892.         ((looking-at "[ \t]*\\([^ \t\n\r:;]+\\)\\([ \t]*-\\*-\\)")
  893.          ;; Simple form: "-*- MODENAME -*-".
  894.          (setq result
  895.            (list (cons 'mode
  896.                (intern (buffer-substring
  897.                     (match-beginning 1)
  898.                     (match-end 1)))))))
  899.         (t
  900.          ;; Hairy form: '-*-' [ <variable> ':' <value> ';' ]* '-*-'
  901.          ;; (last ";" is optional).
  902.          (save-excursion
  903.            (if (search-forward "-*-" end t)
  904.            (setq end (- (point) 3))
  905.          (error "-*- not terminated before end of line")))
  906.          (while (< (point) end)
  907.            (or (looking-at "[ \t]*\\([^ \t\n:]+\\)[ \t]*:[ \t]*")
  908.            (error "malformed -*- line"))
  909.            (goto-char (match-end 0))
  910.            (let ((key (intern (downcase (buffer-substring
  911.                          (match-beginning 1)
  912.                          (match-end 1)))))
  913.              (val (save-restriction
  914.                 (narrow-to-region (point) end)
  915.                 (read (current-buffer)))))
  916.          (setq result (cons (cons key val) result))
  917.          (skip-chars-forward " \t;")))
  918.          (setq result (nreverse result))))
  919.  
  920.       ;; Mode is magic.
  921.       (let (mode)
  922.     (while (setq mode (assq 'mode result))
  923.       (setq mode-p t result (delq mode result))
  924.       (funcall (intern (concat (downcase (symbol-name (cdr mode)))
  925.                    "-mode")))))
  926.       
  927.       (if (and result
  928.            (or (eq enable-local-variables t)
  929.            (and enable-local-variables
  930.             (save-window-excursion
  931.               (switch-to-buffer (current-buffer))
  932.               (y-or-n-p (format "Set local variables as specified in -*- line of %s? "
  933.                         (file-name-nondirectory buffer-file-name)))))))
  934.       (while result
  935.         (let ((key (car (car result)))
  936.           (val (cdr (car result))))
  937.           ;; 'mode has already been removed from this list.
  938.           (hack-one-local-variable key val))
  939.         (setq result (cdr result))))
  940.       mode-p)))
  941.  
  942. (defun hack-local-variables ()
  943.   "Parse and put into effect this buffer's local variables spec."
  944.   (hack-local-variables-prop-line)
  945.   ;; Look for "Local variables:" line in last page.
  946.   (save-excursion
  947.     (goto-char (point-max))
  948.     (search-backward "\n\^L" (max (- (point-max) 3000) (point-min)) 'move)
  949.     (if (let ((case-fold-search t))
  950.       (and (search-forward "Local Variables:" nil t)
  951.            (or (eq enable-local-variables t)
  952.            (and enable-local-variables
  953.             (save-window-excursion
  954.               (switch-to-buffer (current-buffer))
  955.               (save-excursion
  956.                 (beginning-of-line)
  957.                 (set-window-start (selected-window) (point)))
  958.               (y-or-n-p (format "Set local variables as specified at end of %s? "
  959.                         (file-name-nondirectory buffer-file-name))))))))
  960.     (let ((continue t)
  961.           prefix prefixlen suffix beg
  962.           (enable-local-eval enable-local-eval))
  963.       ;; The prefix is what comes before "local variables:" in its line.
  964.       ;; The suffix is what comes after "local variables:" in its line.
  965.       (skip-chars-forward " \t")
  966.       (or (eolp)
  967.           (setq suffix (buffer-substring (point)
  968.                          (progn (end-of-line) (point)))))
  969.       (goto-char (match-beginning 0))
  970.       (or (bolp)
  971.           (setq prefix
  972.             (buffer-substring (point)
  973.                       (progn (beginning-of-line) (point)))))
  974.  
  975.       (if prefix (setq prefixlen (length prefix)
  976.                prefix (regexp-quote prefix)))
  977.       (if suffix (setq suffix (concat (regexp-quote suffix) "$")))
  978.       (while continue
  979.         ;; Look at next local variable spec.
  980.         (if selective-display (re-search-forward "[\n\C-m]")
  981.           (forward-line 1))
  982.         ;; Skip the prefix, if any.
  983.         (if prefix
  984.         (if (looking-at prefix)
  985.             (forward-char prefixlen)
  986.           (error "Local variables entry is missing the prefix")))
  987.         ;; Find the variable name; strip whitespace.
  988.         (skip-chars-forward " \t")
  989.         (setq beg (point))
  990.         (skip-chars-forward "^:\n")
  991.         (if (eolp) (error "Missing colon in local variables entry"))
  992.         (skip-chars-backward " \t")
  993.         (let* ((str (buffer-substring beg (point)))
  994.            (var (read str))
  995.           val)
  996.           ;; Setting variable named "end" means end of list.
  997.           (if (string-equal (downcase str) "end")
  998.           (setq continue nil)
  999.         ;; Otherwise read the variable value.
  1000.         (skip-chars-forward "^:")
  1001.         (forward-char 1)
  1002.         (setq val (read (current-buffer)))
  1003.         (skip-chars-backward "\n")
  1004.         (skip-chars-forward " \t")
  1005.         (or (if suffix (looking-at suffix) (eolp))
  1006.             (error "Local variables entry is terminated incorrectly"))
  1007.         ;; Set the variable.  "Variables" mode and eval are funny.
  1008.         (hack-one-local-variable var val))))))))
  1009.  
  1010. (defconst ignored-local-variables
  1011.   '(enable-local-eval)
  1012.   "Variables to be ignored in a file's local variable spec.")
  1013.  
  1014. ;; "Set" one variable in a local variables spec.
  1015. ;; A few variable names are treated specially.
  1016. (defun hack-one-local-variable (var val)
  1017.   (cond ((eq var 'mode)
  1018.      (funcall (intern (concat (downcase (symbol-name val))
  1019.                   "-mode"))))
  1020.     ((memq var ignored-local-variables)
  1021.      nil)
  1022.     ;; "Setting" eval means either eval it or do nothing.
  1023.     ;; Likewise for setting hook variables.
  1024.     ((or (eq var 'eval)
  1025.          (string-match "-hooks?$\\|-functions?$" (symbol-name var)))
  1026.      (if (and (not (string= (user-login-name) "root"))
  1027.           (or (eq enable-local-eval t)
  1028.               (and enable-local-eval
  1029.                (save-window-excursion
  1030.                  (switch-to-buffer (current-buffer))
  1031.                  (save-excursion
  1032.                    (beginning-of-line)
  1033.                    (set-window-start (selected-window) (point)))
  1034.                  (setq enable-local-eval
  1035.                    (y-or-n-p (format "Process `eval' or hook local variables in file %s? "
  1036.                              (file-name-nondirectory buffer-file-name))))))))
  1037.          (if (eq var 'eval)
  1038.          (save-excursion (eval val))
  1039.            (make-local-variable var)
  1040.            (set var val))
  1041.        (message "Ignoring `eval:' in file's local variables")))
  1042.     ;; Ordinary variable, really set it.
  1043.     (t (make-local-variable var)
  1044.        (set var val))))
  1045.  
  1046.  
  1047. (defun set-visited-file-name (filename)
  1048.   "Change name of file visited in current buffer to FILENAME.
  1049. The next time the buffer is saved it will go in the newly specified file.
  1050. nil or empty string as argument means make buffer not be visiting any file.
  1051. Remember to delete the initial contents of the minibuffer
  1052. if you wish to pass an empty string as the argument."
  1053.   (interactive "FSet visited file name: ")
  1054.   (if filename
  1055.       (setq filename
  1056.         (if (string-equal filename "")
  1057.         nil
  1058.           (expand-file-name filename))))
  1059.   (or (equal filename buffer-file-name)
  1060.       (null filename)
  1061.       (progn
  1062.     (lock-buffer filename)
  1063.     (unlock-buffer)))
  1064.   (setq buffer-file-name filename)
  1065.   (if filename                ; make buffer name reflect filename.
  1066.       (let ((new-name (file-name-nondirectory buffer-file-name)))
  1067.     (if (string= new-name "")
  1068.         (error "Empty file name"))
  1069.     (if (eq system-type 'vax-vms)
  1070.         (setq new-name (downcase new-name)))
  1071.     (setq default-directory (file-name-directory buffer-file-name))
  1072.     (rename-buffer new-name t)))
  1073.   (setq buffer-backed-up nil)
  1074.   (clear-visited-file-modtime)
  1075.   (if filename
  1076.       (progn
  1077.     (setq buffer-file-truename
  1078.           (abbreviate-file-name (file-truename buffer-file-name)))
  1079.     (if find-file-visit-truename
  1080.         (setq buffer-file-name buffer-file-truename))
  1081.     (setq buffer-file-number (nth 10 (file-attributes buffer-file-name))))
  1082.     (setq buffer-file-truename nil buffer-file-number nil))
  1083.   ;; write-file-hooks is normally used for things like ftp-find-file
  1084.   ;; that visit things that are not local files as if they were files.
  1085.   ;; Changing to visit an ordinary local file instead should flush the hook.
  1086.   (kill-local-variable 'write-file-hooks)
  1087.   (kill-local-variable 'local-write-file-hooks)
  1088.   (kill-local-variable 'revert-buffer-function)
  1089.   (kill-local-variable 'backup-inhibited)
  1090.   ;; Turn off backup files for certain file names.
  1091.   ;; Since this is a permanent local, the major mode won't eliminate it.
  1092.   (and (not (funcall backup-enable-predicate buffer-file-name))
  1093.        (progn
  1094.      (make-local-variable 'backup-inhibited)
  1095.      (setq backup-inhibited t)))
  1096.   (let ((oauto buffer-auto-save-file-name))
  1097.     ;; If auto-save was not already on, turn it on if appropriate.
  1098.     (if (not buffer-auto-save-file-name)
  1099.     (and buffer-file-name auto-save-default
  1100.          (auto-save-mode t))
  1101.       ;; If auto save is on, start using a new name.
  1102.       ;; We deliberately don't rename or delete the old auto save
  1103.       ;; for the old visited file name.  This is because perhaps
  1104.       ;; the user wants to save the new state and then compare with the
  1105.       ;; previous state from the auto save file.
  1106.       (setq buffer-auto-save-file-name
  1107.         (make-auto-save-file-name)))
  1108.     ;; Rename the old auto save file if any.
  1109.     (and oauto buffer-auto-save-file-name
  1110.      (file-exists-p oauto)
  1111.      (rename-file oauto buffer-auto-save-file-name t)))
  1112.   (if buffer-file-name
  1113.       (set-buffer-modified-p t)))
  1114.  
  1115. (defun write-file (filename)
  1116.   "Write current buffer into file FILENAME.
  1117. Makes buffer visit that file, and marks it not modified.
  1118. If the buffer is already visiting a file, you can specify
  1119. a directory name as FILENAME, to write a file of the same
  1120. old name in that directory."
  1121. ;;  (interactive "FWrite file: ")
  1122.   (interactive
  1123.    (list (if buffer-file-name
  1124.          (read-file-name "Write file: "
  1125.                  nil nil nil nil)
  1126.        (read-file-name "Write file: "
  1127.                    (cdr (assq 'default-directory
  1128.                       (buffer-local-variables)))
  1129.                    nil nil (buffer-name)))))
  1130.   (or (null filename) (string-equal filename "")
  1131.       (progn
  1132.     ;; If arg is just a directory,
  1133.     ;; use same file name, but in that directory.
  1134.     (if (and (file-directory-p filename) buffer-file-name)
  1135.         (setq filename (concat (file-name-as-directory filename)
  1136.                    (file-name-nondirectory buffer-file-name))))
  1137.     (set-visited-file-name filename)))
  1138.   (set-buffer-modified-p t)
  1139.   (save-buffer))
  1140.  
  1141. (defun backup-buffer ()
  1142.   "Make a backup of the disk file visited by the current buffer, if appropriate.
  1143. This is normally done before saving the buffer the first time.
  1144. If the value is non-nil, it is the result of `file-modes' on the original
  1145. file; this means that the caller, after saving the buffer, should change
  1146. the modes of the new file to agree with the old modes."
  1147.   (if (and make-backup-files (not backup-inhibited)
  1148.        (not buffer-backed-up)
  1149.        (file-exists-p buffer-file-name)
  1150.        (memq (aref (elt (file-attributes buffer-file-name) 8) 0)
  1151.          '(?- ?l)))
  1152.       (let ((real-file-name buffer-file-name)
  1153.         backup-info backupname targets setmodes)
  1154.     ;; If specified name is a symbolic link, chase it to the target.
  1155.     ;; Thus we make the backups in the directory where the real file is.
  1156.     (setq real-file-name (file-chase-links real-file-name))
  1157.     (setq backup-info (find-backup-file-name real-file-name)
  1158.           backupname (car backup-info)
  1159.           targets (cdr backup-info))
  1160. ;;;     (if (file-directory-p buffer-file-name)
  1161. ;;;         (error "Cannot save buffer in directory %s" buffer-file-name))
  1162.         (condition-case ()
  1163.         (let ((delete-old-versions
  1164.            ;; If have old versions to maybe delete,
  1165.            ;; ask the user to confirm now, before doing anything.
  1166.            ;; But don't actually delete til later.
  1167.            (and targets
  1168.             (or (eq trim-versions-without-asking t) (eq trim-versions-without-asking nil))
  1169.             (or trim-versions-without-asking
  1170.                 (y-or-n-p (format "Delete excess backup versions of %s? "
  1171.                           real-file-name))))))
  1172.           ;; Actually write the back up file.
  1173.           (condition-case ()
  1174.           (if (or file-precious-flag
  1175. ;              (file-symlink-p buffer-file-name)
  1176.               backup-by-copying
  1177.               (and backup-by-copying-when-linked
  1178.                    (> (file-nlinks real-file-name) 1))
  1179.               (and backup-by-copying-when-mismatch
  1180.                    (let ((attr (file-attributes real-file-name)))
  1181.                  (or (nth 9 attr)
  1182.                      (/= (nth 2 attr) (user-uid))))))
  1183.               (condition-case ()
  1184.               (copy-file real-file-name backupname t t)
  1185.             (file-error
  1186.              ;; If copying fails because file BACKUPNAME
  1187.              ;; is not writable, delete that file and try again.
  1188.              (if (and (file-exists-p backupname)
  1189.                   (not (file-writable-p backupname)))
  1190.                  (delete-file backupname))
  1191.              (copy-file real-file-name backupname t t)))
  1192.             ;; rename-file should delete old backup.
  1193.             (rename-file real-file-name backupname t)
  1194.             (setq setmodes (file-modes backupname)))
  1195.         (file-error
  1196.          ;; If trouble writing the backup, write it in ~.
  1197.          (setq backupname (expand-file-name "~/%backup%~"))
  1198.          (message "Cannot write backup file; backing up in ~/%%backup%%~")
  1199.          (sleep-for 1)
  1200.          (condition-case ()
  1201.              (copy-file real-file-name backupname t t)
  1202.            (file-error
  1203.             ;; If copying fails because file BACKUPNAME
  1204.             ;; is not writable, delete that file and try again.
  1205.             (if (and (file-exists-p backupname)
  1206.                  (not (file-writable-p backupname)))
  1207.             (delete-file backupname))
  1208.             (copy-file real-file-name backupname t t)))))
  1209.           (setq buffer-backed-up t)
  1210.           ;; Now delete the old versions, if desired.
  1211.           (if delete-old-versions
  1212.           (while targets
  1213.             (condition-case ()
  1214.             (delete-file (car targets))
  1215.               (file-error nil))
  1216.             (setq targets (cdr targets))))
  1217.           setmodes)
  1218.     (file-error nil)))))
  1219.  
  1220. (defun file-name-sans-versions (name &optional keep-backup-version)
  1221.   "Return FILENAME sans backup versions or strings.
  1222. This is a separate procedure so your site-init or startup file can
  1223. redefine it.
  1224. If the optional argument KEEP-BACKUP-VERSION is non-nil,
  1225. we do not remove backup version numbers, only true file version numbers."
  1226.   (let ((handler (find-file-name-handler name)))
  1227.     (if handler
  1228.     (funcall handler 'file-name-sans-versions name keep-backup-version)
  1229.       (substring name 0
  1230.          (if (eq system-type 'vax-vms)
  1231.              ;; VMS version number is (a) semicolon, optional
  1232.              ;; sign, zero or more digits or (b) period, option
  1233.              ;; sign, zero or more digits, provided this is the
  1234.              ;; second period encountered outside of the
  1235.              ;; device/directory part of the file name.
  1236.              (or (string-match ";[---+]?[0-9]*\\'" name)
  1237.              (if (string-match "\\.[^]>:]*\\(\\.[---+]?[0-9]*\\)\\'"
  1238.                        name)
  1239.                  (match-beginning 1))
  1240.              (length name))
  1241.            (if keep-backup-version
  1242.                (length name)
  1243.              (or (string-match "\\.~[0-9]+~\\'" name)
  1244.              (string-match "~\\'" name)
  1245.              (length name))))))))
  1246.  
  1247. (defun make-backup-file-name (file)
  1248.   "Create the non-numeric backup file name for FILE.
  1249. This is a separate function so you can redefine it for customization."
  1250.   (concat file "~"))
  1251.  
  1252. (defun backup-file-name-p (file)
  1253.   "Return non-nil if FILE is a backup file name (numeric or not).
  1254. This is a separate function so you can redefine it for customization.
  1255. You may need to redefine `file-name-sans-versions' as well."
  1256.   (string-match "~$" file))
  1257.  
  1258. ;; This is used in various files.
  1259. ;; The usage of bv-length is not very clean,
  1260. ;; but I can't see a good alternative,
  1261. ;; so as of now I am leaving it alone.
  1262. (defun backup-extract-version (fn)
  1263.   "Given the name of a numeric backup file, return the backup number.
  1264. Uses the free variable `bv-length', whose value should be
  1265. the index in the name where the version number begins."
  1266.   (if (and (string-match "[0-9]+~$" fn bv-length)
  1267.        (= (match-beginning 0) bv-length))
  1268.       (string-to-int (substring fn bv-length -1))
  1269.       0))
  1270.  
  1271. ;; I believe there is no need to alter this behavior for VMS;
  1272. ;; since backup files are not made on VMS, it should not get called.
  1273. (defun find-backup-file-name (fn)
  1274.   "Find a file name for a backup file, and suggestions for deletions.
  1275. Value is a list whose car is the name for the backup file
  1276.  and whose cdr is a list of old versions to consider deleting now."
  1277.   (if (eq version-control 'never)
  1278.       (list (make-backup-file-name fn))
  1279.     (let* ((base-versions (concat (file-name-nondirectory fn) ".~"))
  1280.        (bv-length (length base-versions))
  1281.        (possibilities (file-name-all-completions
  1282.                base-versions
  1283.                (file-name-directory fn)))
  1284.        (versions (sort (mapcar
  1285.                 (function backup-extract-version)
  1286.                 possibilities)
  1287.                '<))
  1288.        (high-water-mark (apply 'max 0 versions))
  1289.        (deserve-versions-p
  1290.         (or version-control
  1291.         (> high-water-mark 0)))
  1292.        (number-to-delete (- (length versions)
  1293.                 kept-old-versions kept-new-versions -1)))
  1294.       (if (not deserve-versions-p)
  1295.       (list (make-backup-file-name fn))
  1296.     (cons (concat fn ".~" (int-to-string (1+ high-water-mark)) "~")
  1297.           (if (and (> number-to-delete 0)
  1298.                        ;; Delete nothing if there is overflow
  1299.                ;; in the number of versions to keep.
  1300.                (>= (+ kept-new-versions kept-old-versions -1) 0))
  1301.           (mapcar (function (lambda (n)
  1302.                       (concat fn ".~" (int-to-string n) "~")))
  1303.               (let ((v (nthcdr kept-old-versions versions)))
  1304.                 (rplacd (nthcdr (1- number-to-delete) v) ())
  1305.                 v))))))))
  1306.  
  1307. (defun file-nlinks (filename)
  1308.   "Return number of names file FILENAME has."
  1309.   (car (cdr (file-attributes filename))))
  1310.  
  1311. (defun file-relative-name-1 (directory)
  1312.   (cond ((string= directory "/")
  1313.      filename)
  1314.     ((string-match (concat "^" (regexp-quote directory))
  1315.                filename)
  1316.      (substring filename (match-end 0)))
  1317.     (t
  1318.      (file-relative-name-1
  1319.       (file-name-directory (substring directory 0 -1))))))
  1320.  
  1321. (defun file-relative-name (filename &optional directory)
  1322.   "Convert FILENAME to be relative to DIRECTORY (default: default-directory)."
  1323.   (setq filename (expand-file-name filename)
  1324.     directory (file-name-as-directory (if directory
  1325.                           (expand-file-name directory)
  1326.                           default-directory)))
  1327.   (file-relative-name-1 directory))
  1328.  
  1329. (defun save-buffer (&optional args)
  1330.   "Save current buffer in visited file if modified.  Versions described below.
  1331. By default, makes the previous version into a backup file
  1332.  if previously requested or if this is the first save.
  1333. With 1 or 3 \\[universal-argument]'s, marks this version
  1334.  to become a backup when the next save is done.
  1335. With 2 or 3 \\[universal-argument]'s,
  1336.  unconditionally makes the previous version into a backup file.
  1337. With argument of 0, never makes the previous version into a backup file.
  1338.  
  1339. If a file's name is FOO, the names of its numbered backup versions are
  1340.  FOO.~i~ for various integers i.  A non-numbered backup file is called FOO~.
  1341. Numeric backups (rather than FOO~) will be made if value of
  1342.  `version-control' is not the atom `never' and either there are already
  1343.  numeric versions of the file being backed up, or `version-control' is
  1344.  non-nil.
  1345. We don't want excessive versions piling up, so there are variables
  1346.  `kept-old-versions', which tells Emacs how many oldest versions to keep,
  1347.  and `kept-new-versions', which tells how many newest versions to keep.
  1348.  Defaults are 2 old versions and 2 new.
  1349. `dired-kept-versions' controls dired's clean-directory (.) command.
  1350. If `trim-versions-without-asking' is nil, system will query user
  1351.  before trimming versions.  Otherwise it does it silently."
  1352.   (interactive "p")
  1353.   (let ((modp (buffer-modified-p))
  1354.     (large (> (buffer-size) 50000))
  1355.     (make-backup-files (and make-backup-files (not (eq args 0)))))
  1356.     (and modp (memq args '(16 64)) (setq buffer-backed-up nil))
  1357.     (if (and modp large) (message "Saving file %s..." (buffer-file-name)))
  1358.     (basic-save-buffer)
  1359.     (and modp (memq args '(4 64)) (setq buffer-backed-up nil))))
  1360.  
  1361. (defun delete-auto-save-file-if-necessary (&optional force)
  1362.   "Delete auto-save file for current buffer if `delete-auto-save-files' is t.
  1363. Normally delete only if the file was written by this Emacs since
  1364. the last real save, but optional arg FORCE non-nil means delete anyway."
  1365.   (and buffer-auto-save-file-name delete-auto-save-files
  1366.        (not (string= buffer-file-name buffer-auto-save-file-name))
  1367.        (or force (recent-auto-save-p))
  1368.        (progn
  1369.      (condition-case ()
  1370.          (delete-file buffer-auto-save-file-name)
  1371.        (file-error nil))
  1372.      (set-buffer-auto-saved))))
  1373.  
  1374. (defun basic-save-buffer ()
  1375.   "Save the current buffer in its visited file, if it has been modified."
  1376.   (interactive)
  1377.   (if (buffer-modified-p)
  1378.       (let ((recent-save (recent-auto-save-p))
  1379.         setmodes tempsetmodes)
  1380.     ;; On VMS, rename file and buffer to get rid of version number.
  1381.     (if (and (eq system-type 'vax-vms)
  1382.          (not (string= buffer-file-name
  1383.                    (file-name-sans-versions buffer-file-name))))
  1384.         (let (buffer-new-name)
  1385.           ;; Strip VMS version number before save.
  1386.           (setq buffer-file-name
  1387.             (file-name-sans-versions buffer-file-name))
  1388.           ;; Construct a (unique) buffer name to correspond.
  1389.           (let ((buf (create-file-buffer (downcase buffer-file-name))))
  1390.         (setq buffer-new-name (buffer-name buf))
  1391.         (kill-buffer buf))
  1392.           (rename-buffer buffer-new-name)))
  1393.     ;; If buffer has no file name, ask user for one.
  1394.     (or buffer-file-name
  1395.         (progn
  1396.           (setq buffer-file-name
  1397.             (expand-file-name (read-file-name "File to save in: ") nil)
  1398.             default-directory (file-name-directory buffer-file-name))
  1399.           (and auto-save-default (not buffer-auto-save-file-name)
  1400.            (auto-save-mode t))))
  1401.     (or (verify-visited-file-modtime (current-buffer))
  1402.         (not (file-exists-p buffer-file-name))
  1403.         (yes-or-no-p
  1404.          (format "%s has changed since visited or saved.  Save anyway? "
  1405.              (file-name-nondirectory buffer-file-name)))
  1406.         (error "Save not confirmed"))
  1407.     (save-restriction
  1408.       (widen)
  1409.       (and (> (point-max) 1)
  1410.            (/= (char-after (1- (point-max))) ?\n)
  1411.            (or (eq require-final-newline t)
  1412.            (and require-final-newline
  1413.             (y-or-n-p
  1414.              (format "Buffer %s does not end in newline.  Add one? "
  1415.                  (buffer-name)))))
  1416.            (save-excursion
  1417.          (goto-char (point-max))
  1418.          (insert ?\n)))
  1419.       (let ((hooks (append write-contents-hooks local-write-file-hooks
  1420.                    write-file-hooks))
  1421.         (done nil))
  1422.         (while (and hooks
  1423.             (not (setq done (funcall (car hooks)))))
  1424.           (setq hooks (cdr hooks)))
  1425.         ;; If a hook returned t, file is already "written".
  1426.         (cond ((not done)
  1427.            (if (not (file-writable-p buffer-file-name))
  1428.                (let ((dir (file-name-directory buffer-file-name)))
  1429.              (if (not (file-directory-p dir))
  1430.                  (error "%s is not a directory" dir)
  1431.                (if (not (file-exists-p buffer-file-name))
  1432.                    (error "Directory %s write-protected" dir)
  1433.                  (if (yes-or-no-p
  1434.                   (format "File %s is write-protected; try to save anyway? "
  1435.                       (file-name-nondirectory
  1436.                        buffer-file-name)))
  1437.                  (setq tempsetmodes t)
  1438.                    (error "Attempt to save to a file which you aren't allowed to write"))))))
  1439.            (or buffer-backed-up
  1440.                (setq setmodes (backup-buffer)))
  1441.            (if file-precious-flag
  1442.                ;; If file is precious, write temp name, then rename it.
  1443.                (let ((dir (file-name-directory buffer-file-name))
  1444.                  (realname buffer-file-name)
  1445.                  tempname temp nogood i succeed)
  1446.              (setq i 0)
  1447.              (setq nogood t)
  1448.              ;; Find the temporary name to write under.
  1449.              (while nogood
  1450.                (setq tempname (format "%s#tmp#%d" dir i))
  1451.                (setq nogood (file-exists-p tempname))
  1452.                (setq i (1+ i)))
  1453.              (unwind-protect
  1454.                  (progn (clear-visited-file-modtime)
  1455.                     (write-region (point-min) (point-max)
  1456.                           tempname nil realname)
  1457.                     (setq succeed t))
  1458.                ;; If writing the temp file fails,
  1459.                ;; delete the temp file.
  1460.                (or succeed (delete-file tempname)))
  1461.              ;; Since we have created an entirely new file
  1462.              ;; and renamed it, make sure it gets the
  1463.              ;; right permission bits set.
  1464.              (setq setmodes (file-modes buffer-file-name))
  1465.              ;; We succeeded in writing the temp file,
  1466.              ;; so rename it.
  1467.              (rename-file tempname buffer-file-name t))
  1468.              ;; If file not writable, see if we can make it writable
  1469.              ;; temporarily while we write it.
  1470.              ;; But no need to do so if we have just backed it up
  1471.              ;; (setmodes is set) because that says we're superseding.
  1472.              (cond ((and tempsetmodes (not setmodes))
  1473.                 ;; Change the mode back, after writing.
  1474.                 (setq setmodes (file-modes buffer-file-name))
  1475.                 (set-file-modes buffer-file-name 511)))
  1476.              (write-region (point-min) (point-max)
  1477.                    buffer-file-name nil t)))))
  1478.       (setq buffer-file-number (nth 10 (file-attributes buffer-file-name)))
  1479.       (if setmodes
  1480.           (condition-case ()
  1481.           (set-file-modes buffer-file-name setmodes)
  1482.         (error nil))))
  1483.     ;; If the auto-save file was recent before this command,
  1484.     ;; delete it now.
  1485.     (delete-auto-save-file-if-necessary recent-save)
  1486.     (run-hooks 'after-save-hooks))
  1487.     (message "(No changes need to be saved)")))
  1488.  
  1489. (defun save-some-buffers (&optional arg exiting)
  1490.   "Save some modified file-visiting buffers.  Asks user about each one.
  1491. Optional argument (the prefix) non-nil means save all with no questions.
  1492. Optional second argument EXITING means ask about certain non-file buffers
  1493.  as well as about file buffers."
  1494.   (interactive "P")
  1495.   (save-window-excursion
  1496.     (if (zerop (map-y-or-n-p
  1497.         (function
  1498.          (lambda (buffer)
  1499.            (and (buffer-modified-p buffer)
  1500.             (or
  1501.              (buffer-file-name buffer)
  1502.              (and exiting
  1503.                   (progn
  1504.                 (set-buffer buffer)
  1505.                 (and buffer-offer-save (> (buffer-size) 0)))))
  1506.             (if arg
  1507.                 t
  1508.               (if (buffer-file-name buffer)
  1509.                   (format "Save file %s? "
  1510.                       (buffer-file-name buffer))
  1511.                 (format "Save buffer %s? "
  1512.                     (buffer-name buffer)))))))
  1513.         (function
  1514.          (lambda (buffer)
  1515.            (set-buffer buffer)
  1516.            (save-buffer)))
  1517.         (buffer-list)
  1518.         '("buffer" "buffers" "save")
  1519.         (list (list ?\C-r (lambda (buf)
  1520.                     (view-buffer buf)
  1521.                     (setq view-exit-action
  1522.                       '(lambda (ignore)
  1523.                          (exit-recursive-edit)))
  1524.                     (recursive-edit)
  1525.                     ;; Return nil to ask about BUF again.
  1526.                     nil)
  1527.                 "display the current buffer"))
  1528.         ))
  1529.     (message "(No files need saving)"))))
  1530.  
  1531. (defun not-modified (&optional arg)
  1532.   "Mark current buffer as unmodified, not needing to be saved.
  1533. With prefix arg, mark buffer as modified, so \\[save-buffer] will save."
  1534.   (interactive "P")
  1535.   (message (if arg "Modification-flag set"
  1536.            "Modification-flag cleared"))
  1537.   (set-buffer-modified-p arg))
  1538.  
  1539. (defun toggle-read-only (&optional arg)
  1540.   "Change whether this buffer is visiting its file read-only.
  1541. With arg, set read-only iff arg is positive."
  1542.   (interactive "P")
  1543.   (setq buffer-read-only
  1544.     (if (null arg)
  1545.             (not buffer-read-only)
  1546.             (> (prefix-numeric-value arg) 0)))
  1547.   ;; Force mode-line redisplay
  1548.   (set-buffer-modified-p (buffer-modified-p)))
  1549.  
  1550. (defun insert-file (filename)
  1551.   "Insert contents of file FILENAME into buffer after point.
  1552. Set mark after the inserted text.
  1553.  
  1554. This function is meant for the user to run interactively.
  1555. Don't call it from programs!  Use `insert-file-contents' instead.
  1556. \(Its calling sequence is different; see its documentation)."
  1557.   (interactive "fInsert file: ")
  1558.   (if (file-directory-p filename)
  1559.       (signal 'file-error (list "Opening input file" "file is a directory"
  1560.                 filename)))
  1561.   (let ((tem (insert-file-contents filename)))
  1562.     (push-mark (+ (point) (car (cdr tem))))))
  1563.  
  1564. (defun append-to-file (start end filename)
  1565.   "Append the contents of the region to the end of file FILENAME.
  1566. When called from a function, expects three arguments,
  1567. START, END and FILENAME.  START and END are buffer positions
  1568. saying what text to write."
  1569.   (interactive "r\nFAppend to file: ")
  1570.   (write-region start end filename t))
  1571.  
  1572. (defun file-newest-backup (filename)
  1573.   "Return most recent backup file for FILENAME or nil if no backups exist."
  1574.   (let* ((filename (expand-file-name filename))
  1575.      (file (file-name-nondirectory filename))
  1576.      (dir  (file-name-directory    filename))
  1577.      (comp (file-name-all-completions file dir))
  1578.      newest)
  1579.     (while comp
  1580.       (setq file (concat dir (car comp))
  1581.         comp (cdr comp))
  1582.       (if (and (backup-file-name-p file)
  1583.            (or (null newest) (file-newer-than-file-p file newest)))
  1584.       (setq newest file)))
  1585.     newest))
  1586.  
  1587. (defun rename-uniquely ()
  1588.   "Rename current buffer to a similar name not already taken.
  1589. This function is useful for creating multiple shell process buffers
  1590. or multiple mail buffers, etc."
  1591.   (interactive)
  1592.   (let* ((new-buf (generate-new-buffer (buffer-name)))
  1593.      (name (buffer-name new-buf)))
  1594.     (kill-buffer new-buf)
  1595.     (rename-buffer name)
  1596.     (set-buffer-modified-p (buffer-modified-p)))) ; force mode line update
  1597.  
  1598. (defun make-directory (dir &optional parents)
  1599.   "Create the directory DIR and any nonexistent parent dirs.
  1600. Interactively, the default choice of directory to create
  1601. is the current default directory for file names.
  1602. That is useful when you have visited a file in a nonexistint directory.
  1603.  
  1604. Noninteractively, the second (optional) argument PARENTS says whether
  1605. to create parent directories if they don't exist."
  1606.   (interactive
  1607.    (list (read-file-name "Make directory: " default-directory default-directory
  1608.              nil nil)
  1609.      t))
  1610.   (let ((handler (find-file-name-handler dir)))
  1611.     (if handler
  1612.     (funcall handler 'make-directory dir parents)
  1613.       (if (not parents)
  1614.       (make-directory-internal dir)
  1615.     (let ((dir (directory-file-name (expand-file-name dir)))
  1616.           create-list)
  1617.       (while (not (file-exists-p dir))
  1618.         (setq create-list (cons dir create-list)        
  1619.           dir (directory-file-name (file-name-directory dir))))
  1620.       (while create-list
  1621.         (make-directory-internal (car create-list))
  1622.         (setq create-list (cdr create-list))))))))
  1623.  
  1624. (put 'revert-buffer-function 'permanent-local t)
  1625. (defvar revert-buffer-function nil
  1626.   "Function to use to revert this buffer, or nil to do the default.")
  1627.  
  1628. (put 'revert-buffer-insert-file-contents-function 'permanent-local t)
  1629. (defvar revert-buffer-insert-file-contents-function nil
  1630.   "Function to use to insert contents when reverting this buffer.
  1631. Gets two args, first the nominal file name to use,
  1632. and second, t if reading the auto-save file.")
  1633.  
  1634. (defun revert-buffer (&optional ignore-auto noconfirm)
  1635.   "Replace the buffer text with the text of the visited file on disk.
  1636. This undoes all changes since the file was visited or saved.
  1637. With a prefix argument, offer to revert from latest auto-save file, if
  1638. that is more recent than the visited file.
  1639.  
  1640. When called from lisp, the first argument is IGNORE-AUTO; only offer
  1641. to revert from the auto-save file when this is nil.  Note that the
  1642. sense of this argument is the reverse of the prefix argument, for the
  1643. sake of backward compatibility.  IGNORE-AUTO is optional, defaulting
  1644. to nil.
  1645.  
  1646. Optional second argument NOCONFIRM means don't ask for confirmation at
  1647. all.
  1648.  
  1649. If the value of `revert-buffer-function' is non-nil, it is called to
  1650. do the work."
  1651.   ;; I admit it's odd to reverse the sense of the prefix argument, but
  1652.   ;; there is a lot of code out there which assumes that the first
  1653.   ;; argument should be t to avoid consulting the auto-save file, and
  1654.   ;; there's no straightforward way to encourage authors to notice a
  1655.   ;; reversal of the argument sense.  So I'm just changing the user
  1656.   ;; interface, but leaving the programmatic interface the same.
  1657.   (interactive (list (not prefix-arg)))
  1658.   (if revert-buffer-function
  1659.       (funcall revert-buffer-function ignore-auto noconfirm)
  1660.     (let* ((opoint (point))
  1661.        (auto-save-p (and (not ignore-auto)
  1662.                  (recent-auto-save-p)
  1663.                  buffer-auto-save-file-name
  1664.                  (file-readable-p buffer-auto-save-file-name)
  1665.                  (y-or-n-p
  1666.    "Buffer has been auto-saved recently.  Revert from auto-save file? ")))
  1667.        (file-name (if auto-save-p
  1668.               buffer-auto-save-file-name
  1669.             buffer-file-name)))
  1670.       (cond ((null file-name)
  1671.          (error "Buffer does not seem to be associated with any file"))
  1672.         ((or noconfirm
  1673.          (yes-or-no-p (format "Revert buffer from file %s? "
  1674.                       file-name)))
  1675.          ;; If file was backed up but has changed since,
  1676.          ;; we shd make another backup.
  1677.          (and (not auto-save-p)
  1678.           (not (verify-visited-file-modtime (current-buffer)))
  1679.           (setq buffer-backed-up nil))
  1680.          ;; Get rid of all undo records for this buffer.
  1681.          (or (eq buffer-undo-list t)
  1682.          (setq buffer-undo-list nil))
  1683.          (let ((buffer-read-only nil)
  1684.            ;; Don't make undo records for the reversion.
  1685.            (buffer-undo-list t))
  1686.            (if revert-buffer-insert-file-contents-function
  1687.            (funcall revert-buffer-insert-file-contents-function
  1688.                 file-name auto-save-p)
  1689.          (if (not (file-exists-p file-name))
  1690.              (error "File %s no longer exists!" file-name))
  1691.          ;; Bind buffer-file-name to nil
  1692.          ;; so that we don't try to lock the file.
  1693.          (let ((buffer-file-name nil))
  1694.            (or auto-save-p
  1695.                (unlock-buffer))
  1696.            (erase-buffer))
  1697.          (insert-file-contents file-name (not auto-save-p))))
  1698.          (goto-char (min opoint (point-max)))
  1699.          (after-find-file nil nil t)
  1700.          t)))))
  1701.  
  1702. (defun recover-file (file)
  1703.   "Visit file FILE, but get contents from its last auto-save file."
  1704.   (interactive
  1705.    (let ((prompt-file buffer-file-name)
  1706.      (file-name nil)
  1707.      (file-dir nil))
  1708.      (and prompt-file
  1709.       (setq file-name (file-name-nondirectory prompt-file)
  1710.         file-dir (file-name-directory prompt-file)))
  1711.      (list (read-file-name "Recover file: "
  1712.                    file-dir nil nil file-name))))
  1713.   (setq file (expand-file-name file))
  1714.   (if (auto-save-file-name-p file) (error "%s is an auto-save file" file))
  1715.   (let ((file-name (let ((buffer-file-name file))
  1716.              (make-auto-save-file-name))))
  1717.     (cond ((not (file-newer-than-file-p file-name file))
  1718.        (error "Auto-save file %s not current" file-name))
  1719.       ((save-window-excursion
  1720.          (if (not (eq system-type 'vax-vms))
  1721.          (with-output-to-temp-buffer "*Directory*"
  1722.            (buffer-disable-undo standard-output)
  1723.            (call-process "ls" nil standard-output nil
  1724.                  (if (file-symlink-p file) "-lL" "-l")
  1725.                  file file-name)))
  1726.          (yes-or-no-p (format "Recover auto save file %s? " file-name)))
  1727.        (switch-to-buffer (find-file-noselect file t))
  1728.        (let ((buffer-read-only nil))
  1729.          (erase-buffer)
  1730.          (insert-file-contents file-name nil))
  1731.        (after-find-file nil nil t))
  1732.       (t (error "Recover-file cancelled.")))))
  1733.  
  1734. (defun kill-some-buffers ()
  1735.   "For each buffer, ask whether to kill it."
  1736.   (interactive)
  1737.   (let ((list (buffer-list)))
  1738.     (while list
  1739.       (let* ((buffer (car list))
  1740.          (name (buffer-name buffer)))
  1741.     (and (not (string-equal name ""))
  1742.          (/= (aref name 0) ? )
  1743.          (yes-or-no-p
  1744.           (format "Buffer %s %s.  Kill? "
  1745.               name
  1746.               (if (buffer-modified-p buffer)
  1747.               "HAS BEEN EDITED" "is unmodified")))
  1748.          (kill-buffer buffer)))
  1749.       (setq list (cdr list)))))
  1750.  
  1751. (defun auto-save-mode (arg)
  1752.   "Toggle auto-saving of contents of current buffer.
  1753. With prefix argument ARG, turn auto-saving on if positive, else off."
  1754.   (interactive "P")
  1755.   (setq buffer-auto-save-file-name
  1756.         (and (if (null arg)
  1757.          (not buffer-auto-save-file-name)
  1758.            (or (eq arg t) (listp arg) (and (integerp arg) (> arg 0))))
  1759.          (if (and buffer-file-name auto-save-visited-file-name
  1760.               (not buffer-read-only))
  1761.          buffer-file-name
  1762.            (make-auto-save-file-name))))
  1763.   (if (interactive-p)
  1764.       (message "Auto-save %s (in this buffer)"
  1765.            (if buffer-auto-save-file-name "on" "off")))
  1766.   buffer-auto-save-file-name)
  1767.  
  1768. (defun rename-auto-save-file ()
  1769.   "Adjust current buffer's auto save file name for current conditions.
  1770. Also rename any existing auto save file, if it was made in this session."
  1771.   (let ((osave buffer-auto-save-file-name))
  1772.     (setq buffer-auto-save-file-name
  1773.       (make-auto-save-file-name))
  1774.     (if (and osave buffer-auto-save-file-name
  1775.          (not (string= buffer-auto-save-file-name buffer-file-name))
  1776.          (not (string= buffer-auto-save-file-name osave))
  1777.          (file-exists-p osave)
  1778.          (recent-auto-save-p))
  1779.     (rename-file osave buffer-auto-save-file-name t))))
  1780.  
  1781. (defun make-auto-save-file-name ()
  1782.   "Return file name to use for auto-saves of current buffer.
  1783. Does not consider `auto-save-visited-file-name' as that variable is checked
  1784. before calling this function.  You can redefine this for customization.
  1785. See also `auto-save-file-name-p'."
  1786.   (if buffer-file-name
  1787.       (concat (file-name-directory buffer-file-name)
  1788.           "#"
  1789.           (file-name-nondirectory buffer-file-name)
  1790.           "#")
  1791.     ;; For non-file bfr, use bfr name and Emacs pid.
  1792.     (expand-file-name (format "#%s#%s#" (buffer-name) (make-temp-name "")))))
  1793.  
  1794. (defun auto-save-file-name-p (filename)
  1795.   "Return non-nil if FILENAME can be yielded by `make-auto-save-file-name'.
  1796. FILENAME should lack slashes.  You can redefine this for customization."
  1797.   (string-match "^#.*#$" filename))
  1798.  
  1799. (defconst list-directory-brief-switches
  1800.   (if (eq system-type 'vax-vms) "" "-CF")
  1801.   "*Switches for list-directory to pass to `ls' for brief listing,")
  1802.  
  1803. (defconst list-directory-verbose-switches
  1804.   (if (eq system-type 'vax-vms)
  1805.       "/PROTECTION/SIZE/DATE/OWNER/WIDTH=(OWNER:10)"
  1806.     "-l")
  1807.   "*Switches for list-directory to pass to `ls' for verbose listing,")
  1808.  
  1809. (defun list-directory (dirname &optional verbose)
  1810.   "Display a list of files in or matching DIRNAME, a la `ls'.
  1811. DIRNAME is globbed by the shell if necessary.
  1812. Prefix arg (second arg if noninteractive) means supply -l switch to `ls'.
  1813. Actions controlled by variables `list-directory-brief-switches'
  1814. and `list-directory-verbose-switches'."
  1815.   (interactive (let ((pfx current-prefix-arg))
  1816.          (list (read-file-name (if pfx "List directory (verbose): "
  1817.                      "List directory (brief): ")
  1818.                        nil default-directory nil)
  1819.                pfx)))
  1820.   (let ((switches (if verbose list-directory-verbose-switches
  1821.             list-directory-brief-switches)))
  1822.     (or dirname (setq dirname default-directory))
  1823.     (setq dirname (expand-file-name dirname))
  1824.     (with-output-to-temp-buffer "*Directory*"
  1825.       (buffer-disable-undo standard-output)
  1826.       (princ "Directory ")
  1827.       (princ dirname)
  1828.       (terpri)
  1829.       (save-excursion
  1830.     (set-buffer "*Directory*")
  1831.     (let ((wildcard (not (file-directory-p dirname))))
  1832.       (insert-directory dirname switches wildcard (not wildcard)))))))
  1833.  
  1834. (defvar insert-directory-program "ls"
  1835.   "Absolute or relative name of the `ls' program used by `insert-directory'.")
  1836.  
  1837. ;; insert-directory
  1838. ;; - must insert _exactly_one_line_ describing FILE if WILDCARD and
  1839. ;;   FULL-DIRECTORY-P is nil.
  1840. ;;   The single line of output must display FILE's name as it was
  1841. ;;   given, namely, an absolute path name.
  1842. ;; - must insert exactly one line for each file if WILDCARD or
  1843. ;;   FULL-DIRECTORY-P is t, plus one optional "total" line
  1844. ;;   before the file lines, plus optional text after the file lines.
  1845. ;;   Lines are delimited by "\n", so filenames containing "\n" are not
  1846. ;;   allowed.
  1847. ;;   File lines should display the basename.
  1848. ;; - must be consistent with
  1849. ;;   - functions dired-move-to-filename, (these two define what a file line is)
  1850. ;;            dired-move-to-end-of-filename,
  1851. ;;         dired-between-files, (shortcut for (not (dired-move-to-filename)))
  1852. ;;            dired-insert-headerline
  1853. ;;            dired-after-subdir-garbage (defines what a "total" line is)
  1854. ;;   - variable dired-subdir-regexp
  1855. (defun insert-directory (file switches &optional wildcard full-directory-p)
  1856.   "Insert directory listing for of FILE, formatted according to SWITCHES.
  1857. Leaves point after the inserted text.
  1858. Optional third arg WILDCARD means treat FILE as shell wildcard.
  1859. Optional fourth arg FULL-DIRECTORY-P means file is a directory and
  1860. switches do not contain `d', so that a full listing is expected.
  1861.  
  1862. This works by running a directory listing program
  1863. whose name is in the variable `insert-directory-program'.
  1864. If WILDCARD, it also runs the shell specified by `shell-file-name'."
  1865.   (let ((handler (find-file-name-handler file)))
  1866.     (if handler
  1867.     (funcall handler 'insert-directory file switches
  1868.          wildcard full-directory-p)
  1869.       (if (eq system-type 'vax-vms)
  1870.       (vms-read-directory file switches (current-buffer))
  1871.     (if wildcard
  1872.         (let ((default-directory (file-name-directory file)))
  1873.           (call-process shell-file-name nil t nil
  1874.                 "-c" (concat insert-directory-program
  1875.                      " -d " switches " "
  1876.                      (file-name-nondirectory file))))
  1877.       ;; Barry Margolin says: "SunOS 4.1.3 (and SV and POSIX?)
  1878.       ;; lists the link if we give a link to a directory - yuck!"
  1879.       ;; That's why we used to chase symlinks.  But we don't want
  1880.       ;; to chase links before passing the filename to ls; that
  1881.       ;; would mean that our line of output would not display
  1882.       ;; FILE's name as given.  To really address the problem that
  1883.       ;; SunOS 4.1.3 has, we need to find the right switch to get
  1884.       ;; a description of the link itself.
  1885.       ;; (let (symlink)
  1886.       ;;   (while (setq symlink (file-symlink-p file))
  1887.       ;;     (setq file symlink)))
  1888.       (call-process insert-directory-program nil t nil switches file))))))
  1889.  
  1890. (defun save-buffers-kill-emacs (&optional arg)
  1891.   "Offer to save each buffer, then kill this Emacs process.
  1892. With prefix arg, silently save all file-visiting buffers, then kill."
  1893.   (interactive "P")
  1894.   (save-some-buffers arg t)
  1895.   (and (or (not (memq t (mapcar (function
  1896.                   (lambda (buf) (and (buffer-file-name buf)
  1897.                              (buffer-modified-p buf))))
  1898.                 (buffer-list))))
  1899.        (yes-or-no-p "Modified buffers exist; exit anyway? "))
  1900.        (or (not (fboundp 'process-list))
  1901.        ;; process-list is not defined on VMS.
  1902.        (let ((processes (process-list))
  1903.          active)
  1904.          (while processes
  1905.            (and (memq (process-status (car processes)) '(run stop open))
  1906.             (let ((val (process-kill-without-query (car processes))))
  1907.               (process-kill-without-query (car processes) val)
  1908.               val)
  1909.             (setq active t))
  1910.            (setq processes (cdr processes)))
  1911.          (or (not active)
  1912.          (yes-or-no-p "Active processes exist; kill them and exit anyway? "))))
  1913.        (kill-emacs)))
  1914.  
  1915. (define-key ctl-x-map "\C-f" 'find-file)
  1916. (define-key ctl-x-map "\C-q" 'toggle-read-only)
  1917. (define-key ctl-x-map "\C-r" 'find-file-read-only)
  1918. (define-key ctl-x-map "\C-v" 'find-alternate-file)
  1919. (define-key ctl-x-map "\C-s" 'save-buffer)
  1920. (define-key ctl-x-map "s" 'save-some-buffers)
  1921. (define-key ctl-x-map "\C-w" 'write-file)
  1922. (define-key ctl-x-map "i" 'insert-file)
  1923. (define-key esc-map "~" 'not-modified)
  1924. (define-key ctl-x-map "\C-d" 'list-directory)
  1925. (define-key ctl-x-map "\C-c" 'save-buffers-kill-emacs)
  1926.  
  1927. (define-key ctl-x-4-map "f" 'find-file-other-window)
  1928. (define-key ctl-x-4-map "r" 'find-file-read-only-other-window)
  1929. (define-key ctl-x-4-map "\C-f" 'find-file-other-window)
  1930. (define-key ctl-x-4-map "b" 'switch-to-buffer-other-window)
  1931. (define-key ctl-x-4-map "\C-o" 'display-buffer)
  1932.  
  1933. (define-key ctl-x-5-map "b" 'switch-to-buffer-other-frame)
  1934. (define-key ctl-x-5-map "f" 'find-file-other-frame)
  1935. (define-key ctl-x-5-map "\C-f" 'find-file-other-frame)
  1936. (define-key ctl-x-5-map "r" 'find-file-read-only-other-frame)
  1937.  
  1938. ;;; files.el ends here
  1939.